Word VBA質問箱 IV

当質問箱は、有志のボランティア精神のおかげで成り立っています。
問題が解決したら、必ずお礼をしましょうね。
本サイトの基本方針をまとめました。こちら をご一読ください。

投稿種別の選択が必要です。ご注意ください。
迷惑投稿防止のため、URLの入力を制限しています。ご了承ください。

  新規投稿 ┃ツリー表示 ┃一覧表示 ┃トピック表示 ┃検索 ┃設定 ┃ホーム  
32 / 306 ﾂﾘｰ ←次へ　｜　前へ→
▼ 【680】脚注番号のフォントを調節するには？ ポンタ 10/3/1(月) 1:11 質問[未読]
【686】Re:脚注番号のフォントを調節するには？ りる 10/5/5(水) 10:00 回答[未読]
【786】Re:脚注番号のフォントを調節するには？ マナ 13/6/13(木) 23:53 発言[未読]
【787】Re:脚注番号のフォントを調節するには？ マナ 13/6/15(土) 15:19 発言[未読]
【686】Re:脚注番号のフォントを調節するには？
回答  りる  - 10/5/5(水) 10:00 -
引用なし
パスワード
   ポンタ さん、こんにちは。
もう見ていないかもしれませんが、チェックしている人もいるようなので書いておきます。

>脚注のフォントサイズを調節する方法は、
>
>For i = 1 To ActiveDocument.Footnotes.Count
>　ActiveDocument.Footnotes.Item(i).Range.Font.Size=フォントサイズ
>Next i
>
>でできますが、これだと、脚注番号のフォントサイズは元のままです。
>
>脚注番号のフォントサイズも調節する方法はありますか？

それらしいObjectが見つけられませんでしたが、手動で選択すればなんとかなるので、マクロで選択して何とかしてみました。

Sub TEMPO()
　 Dim fn1 As Footnote, r1 As Range
　 '脚注の数だけループ
　 For Each fn1 In ActiveDocument.Footnotes
　　　Set r1 = fn1.Range
　　　r1.Select '脚注の文字列を選択
　　　Selection.MoveLeft　'一つ左に移動
　　　Selection.StartOf Unit:=wdLine, Extend:=wdExtend '脚注の数字を選択
　　　'選択後指定
　　　Selection.Font.Name = "Courier New" 'Courier Newに
　　　Selection.Font.Size = 16　　　　　 'サイズを16に
　 Next
　 '
　 Set r1 = Nothing
End Sub
【786】Re:脚注番号のフォントを調節するには？
発言  マナ  - 13/6/13(木) 23:53 -
引用なし
パスワード
   出来てるかな？自信ありません。

Sub test()
　　Dim myRng As Range
　　
　　If ActiveDocument.Footnotes.Count < 1 Then Exit Sub
　　
　　With ActiveWindow.ActivePane.View
　　　　.Type = wdPrintView
　　　　.SeekView = wdSeekMainDocument
　　End With
　　
　　With ActiveDocument.ActiveWindow.View
　　　　.SplitSpecial = wdPaneFootnotes
　　End With

　　ActiveWindow.Panes(2).Activate
　　Selection.HomeKey wdStory
　　Set myRng = Selection.Range

　　With myRng.Find
　　　　.Text = "^f"
　　　　Do While .Execute
　　　　　　myRng.Font.Size = 16
　　　　Loop
　　End With
　　
　　ActiveDocument.ActiveWindow.View.SplitSpecial = wdPaneNone

End Sub
【787】Re:脚注番号のフォントを調節するには？
発言  マナ  - 13/6/15(土) 15:19 -
引用なし
パスワード
   StoryRangesを使えばよかった?

参考にしたサイト
ht tp://word.mvps.org/faqs/customization/ReplaceAnywhere.htm
ht tp://www.relief.jp/itnote/archives/017995.php#extended

Sub test2()
　　Dim myRng As Range
　　
　　If ActiveDocument.Footnotes.Count < 1 Then Exit Sub
　　
　　Set myRng = ActiveDocument.StoryRanges(wdFootnotesStory)

　　With myRng.Find
　　　　.Text = "^f"
　　　　Do While .Execute
　　　　　　myRng.Font.Size = 16
　　　　　　myRng.Font.Name = "Courier New"
　　　　Loop
　　End With

End Sub
  新規投稿 ┃ツリー表示 ┃一覧表示 ┃トピック表示 ┃検索 ┃設定 ┃ホーム  
32 / 306 ﾂﾘｰ ←次へ　｜　前へ→
ページ：  ┃  記事番号：
206491
(SS)C-BOARD v3.8 is Free